An unreplicated factorial experiment

The experiment consisted of 6 animals where each individual was subject to treatments with two factors, P and F. So δ¹³C was measured for each animal that had been exposed to 3 doses of a pesticide, P0, P1 and P2, and fed two different types of food, F1 and F2.

Creation of an artificial unreplicated experiment, the standard deviation is rather low; I used 0.15.:

data a; 
STD=0.15; 
mu=-20; 
array Pl{3} (0, 0, 0); 
array Fl{2} (2, -1); 
do n=1 to 3; 
do m=1 to 2; 
e=STD*rannor(0); 
y=mu+Pl{n}+Fl{m}+e; 
P=n; 
F=m; 
output; 
end; 
end; 
drop Pl1-Pl3 Fl1 Fl2 mu n m;
run;

The complete treatment structure and a single dataset case of observed ‰ δ¹³C were:
P   F        δ¹³C, ‰
P₀ F₁       -18.172   
P₀ F₂       -21.202   
P₁ F₁       -15.381   
P₁ F₂       -17.824   
P₂ F₁       -15.953   
P₂ F₂       -18.880  

The SAS code to analyse these data would be:

proc mixed data=a;
class P F;
model y = P F;
run;

This corresponds to the linear model:

y_ij=μ+P_i+F_j+ε_ij (1)

Where i is the level of P and j is the level of F.

It is rather crucial that the model (1) is correct. It assumes that there is no interaction between P and F as there is no P*F term in (1). With the present example we would have to assure ourselves that the type of food would not interact with the pesticide treatment. In particular, the lack of replication will not allow for an assessment of the possible interaction.

However, tests such as the Tukey's test for nonadditivity could provide some evidence for the lack of interaction by testing the model. This may be done by running these steps (Borkowsky course material):

PROC GLM DATA=a NOPRINT; 
 CLASS P F; 
 MODEL y = P F; 
 OUTPUT OUT=DIAG PREDICTED=YHAT; 
 
DATA DIAG; SET DIAG; 
 NONADD=YHAT**2; 
 
TITLE 'TUKEY TEST FOR NONADDITIVITY -- 1 OBS PER CELL'; 
 
PROC GLM DATA=DIAG; 
 CLASS P F; 
 MODEL y = P F NONADD;
run;quit; 

For the present sample case data the lack of significance of the NONADD (P=39.77%) indicates additivity.

Milliken, G. and Johnson, D.E., 1989. Analysis of Messy Data, Volume 2: Nonreplicated Experiments. Chapman & Hall/CRC.